/* These input files can be found on the SEER Web site */
/* http://seer.cancer.gov/popdata */

/* The All States Combined file for White, Black, and Other */
/* is used for input */
filename in 'id.1990_2020.19ages.txt';

/* All files read into SEER*Prep must end in .txd */
/* We'll keep all Maryland records for 1998-2002 */
filename out 'yr2000_2021.pops.id.txd';

data pops;
  infile in;
  length state_a $ 2;
  input @  1 year     4.
        @  5 state_a  $char2.
        @  7 state_f  2.
        @  9 county   3.
        @ 12 registry 2.
        @ 14 race     1.
        @ 15 origin   1.
        @ 16 sex      1.
        @ 17 age      2.
        @ 19 pop      8.
        ;
  in_research = 1;        
  if 2000<=year<=2020 then output;
  if year = 2020 then do; in_research = 0; year = 2021; output; end; /* we don't have 2021 populations yet, so in meantime, use 2020 for 2021 also - not for publications */
run;

data _null_;
  set pops;
  file out;
  put @  1 year        z4.
      @  5 state_a     $char2.
      @  7 state_f     z2.
      @  9 county      z3.
      @ 12 registry    z2.
      @ 14 race        1.
      @ 15 origin      1.
      @ 16 sex         1.
      @ 17 age         z2.
      @ 19 pop         z8.
      @ 31 in_research 1.
      ;
run;